Using the SD library to print the directory of files on SD card

This example shows how to list the files available in the directory of the SD card. Please click here for more information on the SD library.

Hardware Required

  • Arduino or Genuino board
  • Ethernet Shield (or other board with an SD slot)
  • Formatted SD card

Circuit

image developed using Fritzing. For more circuit examples, see the Fritzing project page

The Arduino or Genuino board has to be connected to the Ethernet Shield and also has a USB cable connected to the computer.

Schematics

image developed using Fritzing. For more circuit examples, see the Fritzing project page

Code

The code below is configured for use with an Ethernet shield, which has an onboard SD slot. In the setup(), SD.begin() names pin 4 as the CS pin. This pin varies depending on the make of shield or board you are using.

The main loop() does nothing because the function that prints out the file directory of "/" of the SD card is called from the setup(). This because we need to see it just once.

The printDirectory function scans through the list of entries and prints on serial every file and directory present. For files the size is printed as well.

/*
  Listfiles

 This example shows how print out the files in a
 directory on a SD card

 The circuit:
 * SD card attached to SPI bus as follows:
 ** MOSI - pin 11
 ** MISO - pin 12
 ** CLK - pin 13
 ** CS - pin 4 (for MKRZero SD: SDCARD_SS_PIN)

 created   Nov 2010
 by David A. Mellis
 modified 9 Apr 2012
 by Tom Igoe
 modified 2 Feb 2014
 by Scott Fitzgerald

 This example code is in the public domain.

 */

#include <SPI.h>
#include <SD.h>

File root;

void setup() {
  // Open serial communications and wait for port to open:
  Serial.begin(9600);
  while (!Serial) {
    ; // wait for serial port to connect. Needed for native USB port only
  }

  Serial.print("Initializing SD card...");

  if (!SD.begin(4)) {
    Serial.println("initialization failed!");
    while (1);
  }
  Serial.println("initialization done.");

  root = SD.open("/");

  printDirectory(root, 0);

  Serial.println("done!");
}

void loop() {
  // nothing happens after setup finishes.
}

void printDirectory(File dir, int numTabs) {
  while (true) {

    File entry =  dir.openNextFile();
    if (! entry) {
      // no more files
      break;
    }
    for (uint8_t i = 0; i < numTabs; i++) {
      Serial.print('\t');
    }
    Serial.print(entry.name());
    if (entry.isDirectory()) {
      Serial.println("/");
      printDirectory(entry, numTabs + 1);
    } else {
      // files have sizes, directories do not
      Serial.print("\t\t");
      Serial.println(entry.size(), DEC);
    }
    entry.close();
  }
}

See Also


  • CardInfo - Get info about your SD card.
  • Datalogger - How to log data from three analog sensors to an SD card.
  • DumpFile - How to read a file from the SD card.
  • Files - How to create and destroy an SD card file.
  • ReadWrite - How to read and write data to and from an SD card.


Last revision 2015/08/18 by SM

Share